// © Michiel Kamermans 2010 - CC 3.0 license (AT-NC)

/**
 * This models a mixed polygon/polybezier shape.
 * Visualisation can be done by transforming it into
 * an SVG element, of the form:
 * 
 *	<svg width="..." height="..." viewBox="0 0 ... ...">
 * 		<path fill="#FF0000" stroke="#000000" style="opacity: 0.3" d="..."/>
 *	</svg>
 *
 */
class PolyShape
{
	// if true, also shows all the bounding boxes
	boolean debug = false;
	void setDebug(boolean d) { debug = d; }
	boolean toggleBBox() { setDebug(!debug); return debug; }
	ArrayList bounds = new ArrayList();

	// administrative
	int width = 0;
	int height = 0;

	// reference from pathshape
	ArrayList points;

	// SVG data, initialised in getSVG()
	String svgheader;
	String path_d = "M 0 0 Z";
	String path;
	String svgfooter;
	
	// SVG document
	XMLElement svgxml;
	
	// PShape based on SVG document
	PShape svg;

	/**
	 * Constructor sets up a left instruction list, buttress list, right instruction list, and
	 * a template SVG object
	 */
	PolyShape(ArrayList points) { 
		this.points = points;
		getSVG();
		svgxml = new XMLElement(svgheader + path + svgfooter);
		svg = new PShapeSVG(svgxml); }

	/**
	 * Add a normal point to the polyshape.
	 */
	void addPoint(int lx, int ly, int rx, int ry) { updateSVG(max(lx,rx),max(ly,ry)); }
	
	/**
	 * Update the SVG data (header width/height and path)
	 */
	void updateSVG(int x, int y)
	{
		if(x>width) { width = x; }
		if(y>height) { height = y; }
		svgxml.setAttribute("width", ""+width);
		svgxml.setAttribute("height", ""+height);
		svgxml.setAttribute("viewBox","0 0 "+width+" "+height);
		updatePath();
	}
	
	/**
	 * Update the string for the "d" parameter for the SVG path
	 */
	void updatePath()
	{
		bounds = new ArrayList();
		path_d = "";
		for(int d=0, end=points.size(); d<end; d++) {
			Point pt = (Point) points.get(d);
			VectorInstruction vi = pt.getLeftSVG();
			if(debug) { bounds.add(vi.getBoundingBox()); }
			path_d += vi.toSVG(); }
		for(int d=points.size()-1; d>=0; d--) {
			Point pt = (Point) points.get(d);
			ArrayList instructions = pt.getRightSVG();
			for(int a=0, end=instructions.size(); a<end; a++) {
				VectorInstruction vi = (VectorInstruction)instructions.get(a);
				if(debug) { bounds.add(vi.getBoundingBox()); }
				path_d += vi.toSVG(); }}
		if(path_d=="") { path_d = "M 0 0 Z"; }
		svgxml.getChild(0).setAttribute("d", path_d);
		svg = new PShapeSVG(svgxml);
	}

	/**
	 * get the SVG string representation for the xml
	 */
	String getSVG() { 
		svgheader = "<?xml version='1.0' encoding='UTF-8' standalone='no'?>\n";
		svgheader += "<svg xmlns='http://www.w3.org/2000/svg' version='1.0' width='"+width+"' height='"+height+"' viewBox='0 0 "+width+" "+height+"'>\n";
		path = "<path fill='#0000FF' stroke='#000000' style='opacity: 0.3' d='"+path_d+"'/>\n";
		svgfooter = "</svg>\n";
		return svgheader + path + svgfooter;
	}

	/**
	 * Draw this polyshape
	 */
	void draw() {
		shape(svg); 
		if(debug) {
			noFill();
			stroke(255,0,0,50);
			for(int v=0, end=bounds.size(); v<end; v++) {
				float[] bbox= (float[]) bounds.get(v);
				int x1 = (int) bbox[0];
				int y1 = (int) bbox[1];
				int x2 = (int) bbox[2];
				int y2 = (int) bbox[3];
				rect(x1,y1,x2-x1,y2-y1); }}}
}